Data » What's Available » Metadata Summary


Correction to G1289

2000 HRS Core (Final Release, Version 1.0)

09/10/02

In the health status respondent-level data file (H00_B) of the Final Core Data Release Version 1.0, variable G1289 has a data error. This is related to an error in 1998 for F1156. Specifically, there were a number of AHEAD respondents who reported having heart disease in 1993 or 1995 (and had not disputed the report as of 1995), who were miscoded on the 1998 preload variable for heart disease, F234 (i.e., coded 0 instead of 1 on F234).

The heart disease preload variable is what determines which version of the heart disease question (B7) is asked in the current wave. Those coded 1 on the preload variable are simply asked to confirm their prior report of heart disease:

    Our records from your last interview in (date) show that you had
    a heart problem.

Unless the R disputes this, the interviewer keys a value of 1 indicating that R still has heart disease.

Those coded 0 on the preload variable are instead asked this version of the question:

    Since your last interview in (date), has a doctor told you that
    you have had a heart attack, have coronary heart disease, angina,
    congestive heart failure, or other heart problems?

In 1998 if the R said no to this question, s/he was coded 5 on F1156 and asked the incorrect version of the B7 question in 2000 (G1289) as well.

To deal with this error, we recommend that the analyst create a new variable, G1289R, for which the 279 respondents who reported having heart disease in 1993 or 1995 and who answered "No" to G1289 in 2000 are assigned a value of 6. The variables used for this recode are D828 (heart disease status in 1995) and F234 (1998 preload for heart disease). Sample SAS code is provided below. You will want to provide equivalent statements if you are using another statistical software package. 279 cases will change from 5 on G1289 to 6 on G1289R. Frequencies before and after the correction are listed below.

Note that this recode will result in a slight overestimate of the number and percent of respondents with heart disease in 2000, because if the 279 respondents had been asked to confirm their prior heart disease, some of them might have disputed it.

If you are interested in using the heart condition follow-up questions in any of your analyses, these are our recommendations: It is unlikely that respondents who had heart disease in the past but no incident report between 1995 and 1998 would respond "Yes" to follow-up questions B7d, B7i, B7kb, B7p, and B7q. Thus, respondents with a value of 6 on G1289 can be assigned values of 5 on G1295, G1301, G1304, G1307, and G1308). We do not recommend recoding any of the other follow-up question variables, as it less clear how respondents would have answered those questions.


=======================================================================================
G1289     B7. HEART CONDITION
          Section: B            Level: Respondent      CAI Reference: Q1289
          Type: Numeric         Width: 1               Decimals: 0

................................................................. ............
Corrected   Uncorrected

   4375        4375     1. YES
      6           6     3. DISPUTES PREVIOUS WAVE RECORD, BUT NOW HAS CONDITION
    160         160     4. DISPUTES PREVIOUS WAVE RECORD, DOES NOT HAVE CONDITION
  14752       15031     5. NO
    279                 6. PRELOAD ERROR: Condition reported at prior wave but said no to new event
      4           4     8. DK (don't know); NA (not ascertained)
      4           4     9. RF (refused)
                    Blank.

=======================================================================================

****************************************************;
** Fixing Heart Disease Variable in HRS 2000 Core **;
****************************************************;

libname in95 'C:\HRS\1995ahd\core\sas';
libname in98 'C:\HRS\1998hrs\core\sas';
libname in00 'C:\HRS\2000hrs\core\sas';

***1995 data with HHID PN and D828;
Proc Sort data=in95.a95b_r(keep=hhid pn d828)
    out=da95;
    by hhid pn;
run;

***1998 preload data with HHID PN and F234;
Proc Sort data=in98.h98pr_r(keep=hhid pn f234)
    out=da98_1;
    by hhid pn;
run;

***2000 preload data with HHID PN and G234;
Proc Sort data=in00.h00pr_r(keep=hhid pn g234)
    out=da00_1;
    by hhid pn;
run;

***2000 data with HHID PN and G1289;
Proc Sort data=in00.h00b_r(keep= hhid pn g1289)
    out=da00_2;
    by hhid pn;
run;

***Merge data together using HHID and PN;
Data All;
    merge da95 da98_1 da00_1 da00_2(in=a);
    by hhid pn;
    if a;

    if d828 eq 1 and f234 eq 0 and g1289 eq 5 then g1289r = 6;
    else g1289r = g1289;
run;

***Check frequencies after correction;
Proc Freq data=all;
    tables g1289 g1289r / nocol norow nopercent missing;
run;


Copyright © 2014 The Regents of the University of Michigan